| Remainder functions | ||
|---|---|---|
 | ||
|
The three remainder functions, illustrated for both §Integer and §Float cases, and for both positive (left column) and negative (right column) divisors. Lines show the §Float case, with unattained limit values indicated with empty circles. Spots show the §Integer case. It is seen that the §Float case coincides with the §Integer case at integer points.
The illustration is included just for fun — when determining which remainder function to use, it is strongly recommended to do that based on the mathematical characterizations rather than this illustration.
| ||
| Source: show/hide — visit | ||
##needs ..Shapes..Layout / shiftoff
##lookin ..Shapes
##lookin ..Shapes..Traits
##lookin ..Shapes..Geometry
##lookin ..Shapes..Graphics
##lookin ..Shapes..Numeric..Math
##unit u = 5mm
den: '3
xMin: '~8
xMax: '8
intMark: [Graphics..fill [circle 3bp]]
holeMark: Traits..@width:0.1bp & Traits..@nonstroking:BW..WHITE | [Graphics..fillstroke [circle 2bp]]
axisHead: [ShapesArrow width:5bp ...]
xAxis: \ dataMin dataMax →
{
Traits..@width:0.3bp
& Text..@size:8bp
|
{
[Graphics..stroke (dataMin,0u)--(dataMax,0u) head:axisHead]
&
[[Data..range begin:[Numeric..Math..ceil dataMin/1u] end:[Numeric..Math..floor dataMax/1u]].foldl
\ p e →
{
x: e * 1u
p
&
[if e ≠ '0 and [modulo e den] = '0
[Graphics..stroke (x,0)--(x,~5bp)] & [[shift (x,~5bp)] [Layout..shiftoff_wlm (Text..newText << (String..newString << x/1u)) Layout..to_bot]]
[Graphics..stroke (x,0)--(x,~3bp)]
]
}
null
]
}
}
yAxis: \ dataMin dataMax →
{
Traits..@width:0.3bp
& Text..@size:8bp
|
{
[Graphics..stroke (0u,dataMin)--(0u,dataMax) head:axisHead]
&
[[Data..range begin:[Numeric..Math..ceil dataMin/1u] end:[Numeric..Math..floor dataMax/1u]].foldl
\ p e →
{
y: e * 1u
p
&
[if e ≠ '0 and [modulo e den] = '0
[Graphics..stroke (0,y)--(~5bp,y)] & [[shift (~5bp,y)] [Layout..shiftoff_wlm (Text..newText << (String..newString << y/1u)) Layout..to_lft]]
[Graphics..stroke (0,y)--(~3bp,y)]
]
}
null
]
}
}
remainderPlot: \ fun den →
{
aden: [abs den]
floatPath:
Traits..@width:0.5bp
|
{
[[Data..range begin:(xMin/aden - '1) end:(xMax/aden)].foldl
\ p e →
{
x1: e * aden * 1u
x2: (e + '1) * aden * 1u
/** To get the corrent limit in all cases, we use the fact that the limit will always be an integer,
** so an approximation is first computed in the interior of the segment, and then rounded.
**/
y1: [Numeric..Math..round [fun (x1/1u + 0.1) den*1.0]] * 1u
y2: [Numeric..Math..round [fun (x2/1u - 0.1) den*1.0]] * 1u
p & [Graphics..stroke (x1,y1)--(x2,y2)]
}
null
]
}
intMarks: [[Data..range begin:xMin end:(xMax + '1)].foldl
\ p e →
{
x: e
y: [fun x den]
p & [[shift (x*1u,y*1u)] intMark]
}
null
]
holeMarks: [[Data..range begin:xMin end:(xMax + '1)].foldl
\ p e →
{
x: e * 1.0
/** Using rounding to get the left and right limits, and also rounding the value at x,
** the logic is simplified since we can use integer equality testing.
**/
y0: [Numeric..Math..round [fun x den*1.0]]
y1: [Numeric..Math..round [fun (x + 0.1) den*1.0]]
y2: [Numeric..Math..round [fun (x - 0.1) den*1.0]]
[Control..cond
[Data..cons y1 ≠ y0 p & [[shift (x*1u,y1*1u)] holeMark]]
[Data..cons y2 ≠ y0 p & [[shift (x*1u,y2*1u)] holeMark]]
[Data..cons true p]
]
}
null
]
viewXMin: (xMin*1.0-0.7)*1u
viewXMax: (xMax*1.0+0.7)*1u
viewYMin: ~(aden*1.0+1.7)*1u
viewYMax: (aden*1.0+1.7)*1u
•plot: newGroup
•plot << [xAxis viewXMin viewXMax]
•plot << [yAxis viewYMin viewYMax]
data: floatPath & intMarks & holeMarks
•plot << [Graphics..clip data [Geometry..rectangle (viewXMin,viewYMin) (viewXMax,viewYMax)]]
Text..@font:Text..Font..COURIER
|
{
•plot << [[shift (0,viewYMax)] [Layout..shiftoff_wlm (Text..newText << (String..newString << [Debug..sourceof fun] << ` ´ << den*1.0)) Layout..to_top]]
}
plot: freeze •plot
[Layout..enlarge_bleedbox plot (2mm,2mm)]
}
remainderPlotPair: \ fun →
[[shift (~10u,0)] [remainderPlot fun den]]
&
[[shift (10u,0)] [remainderPlot fun ~den]]
yPlotStep: 12u
IO..•page << [remainderPlotPair [Debug..locate modulo]] >> [shift (0,~0*yPlotStep)]
IO..•page << [remainderPlotPair [Debug..locate mod]] >> [shift (0,~1*yPlotStep)]
IO..•page << [remainderPlotPair [Debug..locate rem]] >> [shift (0,~2*yPlotStep)]
| ||